cmake_minimum_required(VERSION 3.12)
project(CDI VERSION 1.0.0 LANGUAGES CXX)

# 设置 C++ 标准
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

# 添加编译选项: -g 生成调试信息, -fPIC 位置无关代码
add_compile_options(-g -fPIC)

# 添加地址 sanitizer 选项（用于检测内存错误）
# 仅在 Debug 模式下启用，避免影响 Release 性能
set(SANITIZE_OPTIONS -fsanitize=address)
add_compile_options($<$<CONFIG:Debug>:${SANITIZE_OPTIONS}>)
link_libraries($<$<CONFIG:Debug>:${SANITIZE_OPTIONS}>)

# 配置输出目录
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

# 设置交付目录
get_filename_component(DELIVER_DIR "${CMAKE_BINARY_DIR}/../../Deliver" ABSOLUTE)
message(STATUS "交付目录: ${DELIVER_DIR}")

# 定义交付库目录
set(DELIVER_LIB_DIR "${DELIVER_DIR}/lib")
message(STATUS "交付库目录: ${DELIVER_LIB_DIR}")

# 确保交付库目录存在
if(NOT EXISTS ${DELIVER_LIB_DIR})
    message(FATAL_ERROR "交付库目录不存在: ${DELIVER_LIB_DIR}")
endif()

# 添加链接目录
link_directories(${DELIVER_LIB_DIR})
message(STATUS "添加链接目录: ${DELIVER_LIB_DIR}")

# 设置包含目录（包括交付头文件目录）
set(DELIVER_INCLUDE_DIR "${DELIVER_DIR}/include")
include_directories(
    ${DELIVER_INCLUDE_DIR}
    ${DELIVER_INCLUDE_DIR}/Img_header
)

# 配置源文件
set(SRC_FILES
    CDI.h
    CDI.cpp
    debug.h
    debug.cpp
    DriverManager.h
    DriverManager.cpp
    DrvTree.h
    DrvTree.cpp
    HandleManager.h
    HandleManager.cpp
    Notify_Thread.h
    Notify_Thread.cpp
    PacketCommon.h
    PacketCommon.cpp
    ProcThreadManager.h
    ProcThreadManager.cpp
    LogLocalHelper.cpp
    LogLocalHelper.h
	${DELIVER_INCLUDE_DIR}/PacketAnalizer.h
	${DELIVER_INCLUDE_DIR}/PacketAnalizer.cpp
	${DELIVER_INCLUDE_DIR}/common_api.h
)

# 创建库目标
add_library(CDI SHARED ${SRC_FILES})

# 设置目标属性
set_target_properties(CDI PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION 1
    OUTPUT_NAME "CDI"
)

# 链接依赖库
if(UNIX AND NOT APPLE)
    target_link_libraries(CDI PRIVATE 
    Crc64 
    common_api
    DeviceBus 
    DevTree 
    CcosFileHandle 
    CcosLock 
    CcosThread 
    DPC 
    LocalConfig 
    LogicClient 
    LogicDevice
    NewModelDPC
    OemBusUnit
    ResDataObject
    ContainerDPC
    log4cpp_wrapper
    )
    message(STATUS "已链接: LogicDevice")
endif()

# 确保交付目录结构存在
file(MAKE_DIRECTORY 
    "${DELIVER_DIR}/lib"
    "${DELIVER_DIR}/bin"
    "${DELIVER_DIR}/include"
)

add_custom_command(TARGET CDI POST_BUILD
    COMMENT "===== 复制构建产物到交付目录 ====="
    
     # 1. 准备交付目录（确保目录存在，避免操作失败）
    COMMAND ${CMAKE_COMMAND} -E echo "准备交付目录（lib/bin/include）..."
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/lib"
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/bin"
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/include"
    
    # 2. 复制核心库文件（唯一真实二进制文件，如 libCDI.so.1.0.0）
    COMMAND ${CMAKE_COMMAND} -E echo "复制核心库文件（CDI完整版本）..."
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "$<TARGET_FILE:CDI>"          # 源：完整版本核心库（含全版本号）
        "${DELIVER_DIR}/lib"          # 目标：交付目录的lib文件夹
    
    # 3. 创建主版本符号链接（如 libCDI.so.1 -> libCDI.so.1.0.0）
    # 作用：保障主版本兼容性（升级同主版本号的库时，依赖程序无需重新编译）
    COMMAND ${CMAKE_COMMAND} -E echo "创建主版本符号链接（.so.1 -> 完整版本）..."
    COMMAND ${CMAKE_COMMAND} -E create_symlink
        "$<TARGET_FILE_NAME:CDI>"     # 链接指向的目标（核心库文件名）
        "${DELIVER_DIR}/lib/$<TARGET_SONAME_FILE_NAME:CDI>"  # 链接文件本身（主版本名）
    
    # 4. 创建通用符号链接（如 libCDI.so -> libCDI.so.1）
    # 作用：简化编译链接，其他项目可通过 -lCDI 直接引用
    COMMAND ${CMAKE_COMMAND} -E echo "创建通用符号链接（.so -> 主版本）..."
    COMMAND ${CMAKE_COMMAND} -E create_symlink
        "$<TARGET_SONAME_FILE_NAME:CDI>"  # 链接指向的目标（主版本链接名）
        "${DELIVER_DIR}/lib/$<TARGET_LINKER_FILE_NAME:CDI>"  # 链接文件本身（通用名）
    
    # 复制头文件
    COMMAND ${CMAKE_COMMAND} -E echo "复制头文件..."
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/include"
)

set(HEADER_NAMES CDI)

# 一次性复制所有头文件
foreach(header_name IN LISTS HEADER_NAMES)
    if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${header_name}.h")
        list(APPEND HEADERS_TO_COPY "${CMAKE_CURRENT_SOURCE_DIR}/${header_name}.h")
    elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${header_name}.hpp")
        list(APPEND HEADERS_TO_COPY "${CMAKE_CURRENT_SOURCE_DIR}/${header_name}.hpp")
    else()
        message(WARNING "未找到头文件: ${header_name}.h 或 ${header_name}.hpp")
    endif()
endforeach()

# 添加单个复制命令复制所有头文件
if(HEADERS_TO_COPY)
    add_custom_command(TARGET CDI POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy_if_different
            ${HEADERS_TO_COPY}
            "${DELIVER_DIR}/include"
        COMMENT "复制头文件到交付目录"
    )
endif()