DriverPlatform-V3.1/OemLayer/OemBusUnit/CMakeLists.txt

cmake_minimum_required(VERSION 3.12)
project(OemBusUnit VERSION 1.0.0 LANGUAGES CXX)

# 设置 C++ 标准
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

# 添加编译选项: -g 生成调试信息, -fPIC 位置无关代码
add_compile_options(-g -fPIC)

# 添加地址 sanitizer 选项（用于检测内存错误）
# 仅在 Debug 模式下启用，避免影响 Release 性能
set(SANITIZE_OPTIONS -fsanitize=address)
add_compile_options($<$<CONFIG:Debug>:${SANITIZE_OPTIONS}>)
link_libraries($<$<CONFIG:Debug>:${SANITIZE_OPTIONS}>)

# 配置输出目录
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

# 设置交付目录
get_filename_component(DELIVER_DIR "${CMAKE_BINARY_DIR}/../../Deliver" ABSOLUTE)
message(STATUS "交付目录: ${DELIVER_DIR}")

# 定义交付库目录
set(DELIVER_LIB_DIR "${DELIVER_DIR}/lib")
message(STATUS "交付库目录: ${DELIVER_LIB_DIR}")

# 确保交付库目录存在
if(NOT EXISTS ${DELIVER_LIB_DIR})
    message(FATAL_ERROR "交付库目录不存在: ${DELIVER_LIB_DIR}")
endif()

# 添加链接目录
link_directories(${DELIVER_LIB_DIR})
message(STATUS "添加链接目录: ${DELIVER_LIB_DIR}")

# 设置包含目录（包括交付头文件目录）
set(DELIVER_INCLUDE_DIR "${DELIVER_DIR}/include")
include_directories(
    ${DELIVER_INCLUDE_DIR}
)

# 配置源文件
set(SRC_FILES
    BusUnitClient.h
    BusUnitClient.cpp
    BusUnitLogic.h
    BusUnitLogic.cpp
    DriverConfigManager.h
    DriverConfigManager.cpp
    OemBusUnit.h
    OemBusUnit.cpp
    OemBusUnitDevice.h
    OemBusUnitDevice.cpp
	${DELIVER_INCLUDE_DIR}/PacketAnalizer.h
	${DELIVER_INCLUDE_DIR}/PacketAnalizer.cpp
	${DELIVER_INCLUDE_DIR}/common_api.h
)

# 创建库目标
add_library(OemBusUnit SHARED ${SRC_FILES})

# 设置目标属性
set_target_properties(OemBusUnit PROPERTIES
    VERSION ${PROJECT_VERSION}
    SOVERSION 1
    OUTPUT_NAME "OemBusUnit"
)

# 链接依赖库
if(UNIX AND NOT APPLE)
    target_link_libraries(OemBusUnit PRIVATE common_api LogicDevice LogicClient LogicDriver)
    message(STATUS "已链接: LogicDevice LogicClient LogicDriver")
endif()

# 确保交付目录结构存在
file(MAKE_DIRECTORY 
    "${DELIVER_DIR}/lib"
    "${DELIVER_DIR}/bin"
    "${DELIVER_DIR}/include"
)

add_custom_command(TARGET OemBusUnit POST_BUILD
    COMMENT "===== 复制构建产物到交付目录 ====="
    
    # 复制动态库/导入库
    COMMAND ${CMAKE_COMMAND} -E echo "复制库文件..."
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/lib"
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/bin"
    
     # 复制主库文件 (libDPC.so.1.0.0)
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "$<TARGET_FILE:OemBusUnit>"
        "${DELIVER_DIR}/lib"
    
    # 复制符号链接 (libDPC.so 和 libDPC.so.1)
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "$<TARGET_LINKER_FILE:OemBusUnit>"
        "${DELIVER_DIR}/lib"
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
        "$<TARGET_SONAME_FILE:OemBusUnit>"
        "${DELIVER_DIR}/lib"
    
    # 复制头文件
    COMMAND ${CMAKE_COMMAND} -E echo "复制头文件..."
    COMMAND ${CMAKE_COMMAND} -E make_directory "${DELIVER_DIR}/include"
)

# 单独处理头文件复制（支持多配置生成器）
set(HEADER_TO_COPY)
if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/OemBusUnit.h")
    set(HEADER_TO_COPY "${CMAKE_CURRENT_SOURCE_DIR}/OemBusUnit.h")
elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/OemBusUnit.hpp")
    set(HEADER_TO_COPY "${CMAKE_CURRENT_SOURCE_DIR}/OemBusUnit.hpp")
endif()

if(HEADER_TO_COPY)
    add_custom_command(TARGET OemBusUnit POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy_if_different
            "${HEADER_TO_COPY}"
            "${DELIVER_DIR}/include"
        COMMENT "复制头文件: ${HEADER_TO_COPY}"
    )
else()
    message(WARNING "未找到与目标 OemBusUnit 同名的头文件")
endif()